Bullet Collision

2012-05-11T13:10:19Z

New page

This example shows how to use SphereCollision to perform bullet collisions.
Use arrows to move and spacebar to shoot.

<flash>file=http://wiki.flare3d.com/demos/collisionsExample.swf|width=800|height=450|quality=best|wmode=direct</flash>

== Usage Example ==

<syntaxhighlight lang="actionscript">
package
{
import flare.basic.Scene3D;
import flare.basic.Viewer3D;
import flare.materials.filters.ColorFilter;
import flare.materials.filters.LightFilter;
import flare.materials.Shader3D;
import flare.primitives.Cube;
import flare.primitives.Cylinder;
import flare.primitives.Plane;
import flare.system.Input3D;
import flare.utils.Pivot3DUtils;
import flash.display.Sprite;
import flash.events.Event;

/**
* ...
* @author Ivan Vodopiviz
*/

[SWF(frameRate = 60, width = 800, height = 450, backgroundColor = 0x000000)]

public class Main extends Sprite
{
private var _scene:Scene3D;

private var _floor:Plane = new Plane( "", 500, 500 );
private var _player:Cube = new Cube();
private var _bulletMesh:Cube = new Cube( "", 2, 2 );

private var _enemyPool:Vector.<Cube> = new Vector.<Cube>( 20 );
private var _bulletPool:Vector.<Bullet> = new Vector.<Bullet>( 100 );

private var _playerMaterial:Shader3D;
private var _enemyMaterial:Shader3D;

public function Main():void
{
_scene = new Viewer3D( this );
_scene.antialias = 2;

_scene.camera.setPosition( 50, 60, -100 );
_scene.camera.lookAt( 0, 0, 0 );

_scene.addChild( _floor );
_floor.setRotation( 90, 0, 0 );

_scene.addChild( _player );
_player.setPosition( 0, _player.height / 2, 0 );

_scene.addEventListener( Scene3D.UPDATE_EVENT, updateEvent );

init();
}

private function init():void
{
// create materials
_playerMaterial = new Shader3D( "", [new ColorFilter( 0x0000ff )] );
_player.setMaterial( _playerMaterial );

var cannon:Cylinder = new Cylinder( "", 2 , 20 );
_player.addChild( cannon );
cannon.rotateX( 90 );

_enemyMaterial = new Shader3D( "", [new ColorFilter( 0x00ff00 )] );

// create enemies
for ( var j:int = 0; j < _enemyPool.length; j++ )
{
var newEnemy:Cube = new Cube();
_enemyPool[j] = newEnemy;

_scene.addChild( newEnemy );
newEnemy.setPosition( -200 * Math.random(), newEnemy.height / 2, 200 * Math.random() );
newEnemy.setMaterial( _enemyMaterial );
}

// create bullets
for ( var i:int = 0; i < _bulletPool.length; i++ )
{
var newBullet:Bullet = new Bullet( _bulletMesh.clone() );
_bulletPool[i] = newBullet;
newBullet.visible = false;

_scene.addChild( newBullet );
newBullet.setCollitions( _enemyPool );
}
}

private function updateEvent( e:Event ):void
{

if ( Input3D.keyDown( Input3D.UP ) ) _player.translateZ( 3 );
if ( Input3D.keyDown( Input3D.DOWN ) ) _player.translateZ( -3 );
if ( Input3D.keyDown( Input3D.LEFT ) ) _player.rotateY( -3 );
if ( Input3D.keyDown( Input3D.RIGHT ) ) _player.rotateY( 3 );

if ( Input3D.keyHit( Input3D.SPACE ) ) fireBullet();

Pivot3DUtils.setPositionWithReference( _scene.camera, 0, 20, -40, _player, 0.1 );
Pivot3DUtils.lookAtWithReference( _scene.camera, 0, 0, 0, _player );
}

private function fireBullet():void
{
for each ( var bullet:Bullet in _bulletPool )
{
if ( !bullet.alive )
{
bullet.resetAt( _player );
break;
}
}
}
}
}

import flare.collisions.CollisionInfo;
import flare.collisions.SphereCollision;
import flare.core.Mesh3D;
import flare.core.Pivot3D;
import flare.materials.filters.ColorFilter;
import flare.materials.Shader3D;
import flare.primitives.Cube;
import flare.utils.Vector3DUtils;
import flash.events.Event;
import flash.geom.Vector3D;

class Bullet extends Pivot3D
{
private var _alive:Boolean = false;
private var _traveled:Number = 0;
private var _collision:SphereCollision;

private var _deadEnemyMaterial:Shader3D;

public function Bullet( mesh:Pivot3D )
{
super();

addChild( mesh );
_collision = new SphereCollision( this );

addEventListener( Pivot3D.ENTER_FRAME_EVENT, updateEvent );

_deadEnemyMaterial = new Shader3D( "", [new ColorFilter( 0xff0000 )] );
}

public function setCollitions( enemies:Vector.<Cube> ):void
{
for each ( var cube:Cube in enemies )
{
_collision.addCollisionWith( cube );
}
}

private function updateEvent( e:Event ):void
{
translateZ( 10 );
_traveled += 10;

if ( alive )
{
if ( _traveled > 1500 )
{
alive = false;
}

if ( _collision.fixed() )
{
var collisionInfo:CollisionInfo = _collision.data[0];
collisionInfo.mesh.setMaterial( _deadEnemyMaterial );

var dir:Vector3D = getDir(false);

Vector3DUtils.mirror( dir, collisionInfo.normal, dir );

setOrientation( dir );
}
}
}

public function resetAt( pivot:Pivot3D ):void
{
_traveled = 0;

copyTransformFrom( pivot );
_collision.reset();

alive = true;
}

public function get alive():Boolean
{
return _alive;
}

public function set alive( value:Boolean ):void
{
_alive = value;
visible = value;
}
}
</syntaxhighlight>

Code Utilities

2012-05-10T19:41:38Z

Added bullet collision tutorial

← Older revision		Revision as of 19:41, 10 May 2012
Line 43:		Line 43:

	*[[Verlets / Cloths]] - This example shows a physics integration using verlets to simulate cloths.		*[[Verlets / Cloths]] - This example shows a physics integration using verlets to simulate cloths.
		+
		+	*[[Bullet Collision]] - This example shows how to use SphereCollisions to perform bullet collisions.

Flare3D - WIKI - Recent changes [en]

Bullet Collision

Code Utilities